From 0d2c065e524da9cfae731326a064f71a1d076d94 Mon Sep 17 00:00:00 2001
From: Skylar Hill <stellarskylark@posteo.net>
Date: Tue, 5 Dec 2023 15:22:31 -0600
Subject: [PATCH] Various changes to Fish config

---
 fish/completions/fisher.fish           |   7 +
 fish/conf.d/done.fish                  | 335 +++++++++++++++++++++++++
 fish/config.fish                       |   4 +-
 fish/fish_plugins                      |   3 +
 fish/fish_variables                    |  67 +++--
 fish/functions/fisher.fish             | 240 ++++++++++++++++++
 fish/themes/Catppuccin Frappe.theme    |  30 +++
 fish/themes/Catppuccin Latte.theme     |  30 +++
 fish/themes/Catppuccin Macchiato.theme |  30 +++
 fish/themes/Catppuccin Mocha.theme     |  30 +++
 10 files changed, 751 insertions(+), 25 deletions(-)
 create mode 100644 fish/completions/fisher.fish
 create mode 100644 fish/conf.d/done.fish
 create mode 100644 fish/fish_plugins
 create mode 100644 fish/functions/fisher.fish
 create mode 100644 fish/themes/Catppuccin Frappe.theme
 create mode 100644 fish/themes/Catppuccin Latte.theme
 create mode 100644 fish/themes/Catppuccin Macchiato.theme
 create mode 100644 fish/themes/Catppuccin Mocha.theme

diff --git a/fish/completions/fisher.fish b/fish/completions/fisher.fish
new file mode 100644
index 0000000..6d23ce4
--- /dev/null
+++ b/fish/completions/fisher.fish
@@ -0,0 +1,7 @@
+complete --command fisher --exclusive --long help --description "Print help"
+complete --command fisher --exclusive --long version --description "Print version"
+complete --command fisher --exclusive --condition __fish_use_subcommand --arguments install --description "Install plugins"
+complete --command fisher --exclusive --condition __fish_use_subcommand --arguments update --description "Update installed plugins"
+complete --command fisher --exclusive --condition __fish_use_subcommand --arguments remove --description "Remove installed plugins"
+complete --command fisher --exclusive --condition __fish_use_subcommand --arguments list --description "List installed plugins matching regex"
+complete --command fisher --exclusive --condition "__fish_seen_subcommand_from update remove" --arguments "(fisher list)"
diff --git a/fish/conf.d/done.fish b/fish/conf.d/done.fish
new file mode 100644
index 0000000..56fe789
--- /dev/null
+++ b/fish/conf.d/done.fish
@@ -0,0 +1,335 @@
+# MIT License
+
+# Copyright (c) 2016 Francisco Lourenço & Daniel Wehner
+
+# Permission is hereby granted, free of charge, to any person obtaining a copy
+# of this software and associated documentation files (the "Software"), to deal
+# in the Software without restriction, including without limitation the rights
+# to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+# copies of the Software, and to permit persons to whom the Software is
+# furnished to do so, subject to the following conditions:
+
+# The above copyright notice and this permission notice shall be included in all
+# copies or substantial portions of the Software.
+
+# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+# OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+# SOFTWARE.
+
+if not status is-interactive
+    exit
+end
+
+set -g __done_version 1.19.1
+
+function __done_run_powershell_script
+    set -l powershell_exe (command --search "powershell.exe")
+
+    if test $status -ne 0
+        and command --search wslvar
+
+        set -l powershell_exe (wslpath (wslvar windir)/System32/WindowsPowerShell/v1.0/powershell.exe)
+    end
+
+    if string length --quiet "$powershell_exe"
+        and test -x "$powershell_exe"
+
+        set cmd (string escape $argv)
+
+        eval "$powershell_exe -Command $cmd"
+    end
+end
+
+function __done_windows_notification -a title -a message
+    if test "$__done_notify_sound" -eq 1
+        set soundopt "<audio silent=\"false\" src=\"ms-winsoundevent:Notification.Default\" />"
+    else
+        set soundopt "<audio silent=\"true\" />"
+    end
+
+    __done_run_powershell_script "
+[Windows.Data.Xml.Dom.XmlDocument, Windows.Data.Xml.Dom.XmlDocument, ContentType = WindowsRuntime] | Out-Null
+[Windows.UI.Notifications.ToastNotification, Windows.UI.Notifications, ContentType = WindowsRuntime] | Out-Null
+
+\$toast_xml_source = @\"
+    <toast>
+        $soundopt
+        <visual>
+            <binding template=\"ToastText02\">
+                <text id=\"1\">$title</text>
+                <text id=\"2\">$message</text>
+            </binding>
+        </visual>
+    </toast>
+\"@
+
+\$toast_xml = New-Object Windows.Data.Xml.Dom.XmlDocument
+\$toast_xml.loadXml(\$toast_xml_source)
+
+\$toast = New-Object Windows.UI.Notifications.ToastNotification \$toast_xml
+
+[Windows.UI.Notifications.ToastNotificationManager]::CreateToastNotifier(\"fish\").Show(\$toast)
+"
+end
+
+function __done_get_focused_window_id
+    if type -q lsappinfo
+        lsappinfo info -only bundleID (lsappinfo front | string replace 'ASN:0x0-' '0x') | cut -d '"' -f4
+    else if test -n "$SWAYSOCK"
+        and type -q jq
+        swaymsg --type get_tree | jq '.. | objects | select(.focused == true) | .id'
+    else if test -n "$HYPRLAND_INSTANCE_SIGNATURE"
+        hyprctl activewindow | awk 'NR==13 {print $2}'
+    else if begin
+            test "$XDG_SESSION_DESKTOP" = gnome; and type -q gdbus
+        end
+        gdbus call --session --dest org.gnome.Shell --object-path /org/gnome/Shell --method org.gnome.Shell.Eval 'global.display.focus_window.get_id()'
+    else if type -q xprop
+        and test -n "$DISPLAY"
+        # Test that the X server at $DISPLAY is running
+        and xprop -grammar >/dev/null 2>&1
+        xprop -root 32x '\t$0' _NET_ACTIVE_WINDOW | cut -f 2
+    else if uname -a | string match --quiet --ignore-case --regex microsoft
+        __done_run_powershell_script '
+Add-Type @"
+    using System;
+    using System.Runtime.InteropServices;
+    public class WindowsCompat {
+        [DllImport("user32.dll")]
+        public static extern IntPtr GetForegroundWindow();
+    }
+"@
+[WindowsCompat]::GetForegroundWindow()
+'
+    else if set -q __done_allow_nongraphical
+        echo 12345 # dummy value
+    end
+end
+
+function __done_is_tmux_window_active
+    set -q fish_pid; or set -l fish_pid %self
+
+    # find the outermost process within tmux
+    # ppid != "tmux" -> pid = ppid
+    # ppid == "tmux" -> break
+    set tmux_fish_pid $fish_pid
+    while set tmux_fish_ppid (ps -o ppid= -p $tmux_fish_pid | string trim)
+        # remove leading hyphen so that basename does not treat it as an argument (e.g. -fish), and return only
+        # the actual command and not its arguments so that basename finds the correct command name.
+        # (e.g. '/usr/bin/tmux' from command '/usr/bin/tmux new-session -c /some/start/dir')
+        and ! string match -q "tmux*" (basename (ps -o command= -p $tmux_fish_ppid | string replace -r '^-' '' | string split ' ')[1])
+        set tmux_fish_pid $tmux_fish_ppid
+    end
+
+    # tmux session attached and window is active -> no notification
+    # all other combinations -> send notification
+    tmux list-panes -a -F "#{session_attached} #{window_active} #{pane_pid}" | string match -q "1 1 $tmux_fish_pid"
+end
+
+function __done_is_screen_window_active
+    string match --quiet --regex "$STY\s+\(Attached" (screen -ls)
+end
+
+function __done_is_process_window_focused
+    # Return false if the window is not focused
+
+    if set -q __done_allow_nongraphical
+        return 1
+    end
+
+    if set -q __done_kitty_remote_control
+        kitty @ --password="$__done_kitty_remote_control_password" ls | jq -e ".[].tabs[] | select(any(.windows[]; .is_self)) | .is_focused" >/dev/null
+        return $status
+    end
+
+    set __done_focused_window_id (__done_get_focused_window_id)
+    if test "$__done_sway_ignore_visible" -eq 1
+        and test -n "$SWAYSOCK"
+        string match --quiet --regex "^true" (swaymsg -t get_tree | jq ".. | objects | select(.id == "$__done_initial_window_id") | .visible")
+        return $status
+    else if test -n "$HYPRLAND_INSTANCE_SIGNATURE"
+        and test $__done_initial_window_id -eq (hyprctl activewindow | awk 'NR==13 {print $2}')
+        return $status
+    else if test "$__done_initial_window_id" != "$__done_focused_window_id"
+        return 1
+    end
+    # If inside a tmux session, check if the tmux window is focused
+    if type -q tmux
+        and test -n "$TMUX"
+        __done_is_tmux_window_active
+        return $status
+    end
+
+    # If inside a screen session, check if the screen window is focused
+    if type -q screen
+        and test -n "$STY"
+        __done_is_screen_window_active
+        return $status
+    end
+
+    return 0
+end
+
+function __done_humanize_duration -a milliseconds
+    set -l seconds (math --scale=0 "$milliseconds/1000" % 60)
+    set -l minutes (math --scale=0 "$milliseconds/60000" % 60)
+    set -l hours (math --scale=0 "$milliseconds/3600000")
+
+    if test $hours -gt 0
+        printf '%s' $hours'h '
+    end
+    if test $minutes -gt 0
+        printf '%s' $minutes'm '
+    end
+    if test $seconds -gt 0
+        printf '%s' $seconds's'
+    end
+end
+
+# verify that the system has graphical capabilities before initializing
+if test -z "$SSH_CLIENT" # not over ssh
+    and count (__done_get_focused_window_id) >/dev/null # is able to get window id
+    set __done_enabled
+end
+
+if set -q __done_allow_nongraphical
+    and set -q __done_notification_command
+    set __done_enabled
+end
+
+if set -q __done_enabled
+    set -g __done_initial_window_id ''
+    set -q __done_min_cmd_duration; or set -g __done_min_cmd_duration 5000
+    set -q __done_exclude; or set -g __done_exclude '^git (?!push|pull|fetch)'
+    set -q __done_notify_sound; or set -g __done_notify_sound 0
+    set -q __done_sway_ignore_visible; or set -g __done_sway_ignore_visible 0
+    set -q __done_tmux_pane_format; or set -g __done_tmux_pane_format '[#{window_index}]'
+    set -q __done_notification_duration; or set -g __done_notification_duration 3000
+
+    function __done_started --on-event fish_preexec
+        set __done_initial_window_id (__done_get_focused_window_id)
+    end
+
+    function __done_ended --on-event fish_postexec
+        set -l exit_status $status
+
+        # backwards compatibility for fish < v3.0
+        set -q cmd_duration; or set -l cmd_duration $CMD_DURATION
+
+        if test $cmd_duration
+            and test $cmd_duration -gt $__done_min_cmd_duration # longer than notify_duration
+            and not __done_is_process_window_focused # process pane or window not focused
+
+            # don't notify if command matches exclude list
+            for pattern in $__done_exclude
+                if string match -qr $pattern $argv[1]
+                    return
+                end
+            end
+
+            # Store duration of last command
+            set -l humanized_duration (__done_humanize_duration "$cmd_duration")
+
+            set -l title "Done in $humanized_duration"
+            set -l wd (string replace --regex "^$HOME" "~" (pwd))
+            set -l message "$wd/ $argv[1]"
+            set -l sender $__done_initial_window_id
+
+            if test $exit_status -ne 0
+                set title "Failed ($exit_status) after $humanized_duration"
+            end
+
+            if test -n "$TMUX_PANE"
+                set message (tmux lsw  -F"$__done_tmux_pane_format" -f '#{==:#{pane_id},'$TMUX_PANE'}')" $message"
+            end
+
+            if set -q __done_notification_command
+                eval $__done_notification_command
+                if test "$__done_notify_sound" -eq 1
+                    echo -e "\a" # bell sound
+                end
+            else if set -q KITTY_WINDOW_ID
+                printf "\x1b]99;i=done:d=0;$title\x1b\\"
+                printf "\x1b]99;i=done:d=1:p=body;$message\x1b\\"
+            else if type -q terminal-notifier # https://github.com/julienXX/terminal-notifier
+                if test "$__done_notify_sound" -eq 1
+                    # pipe message into terminal-notifier to avoid escaping issues (https://github.com/julienXX/terminal-notifier/issues/134). fixes #140
+                    echo "$message" | terminal-notifier -title "$title" -sender "$__done_initial_window_id" -sound default
+                else
+                    echo "$message" | terminal-notifier -title "$title" -sender "$__done_initial_window_id"
+                end
+
+            else if type -q osascript # AppleScript
+                # escape double quotes that might exist in the message and break osascript. fixes #133
+                set -l message (string replace --all '"' '\"' "$message")
+                set -l title (string replace --all '"' '\"' "$title")
+
+                osascript -e "display notification \"$message\" with title \"$title\""
+                if test "$__done_notify_sound" -eq 1
+                    osascript -e "display notification \"$message\" with title \"$title\" sound name \"Glass\""
+                else
+                    osascript -e "display notification \"$message\" with title \"$title\""
+                end
+
+            else if type -q notify-send # Linux notify-send
+                # set urgency to normal
+                set -l urgency normal
+
+                # use user-defined urgency if set
+                if set -q __done_notification_urgency_level
+                    set urgency "$__done_notification_urgency_level"
+                end
+                # override user-defined urgency level if non-zero exitstatus
+                if test $exit_status -ne 0
+                    set urgency critical
+                    if set -q __done_notification_urgency_level_failure
+                        set urgency "$__done_notification_urgency_level_failure"
+                    end
+                end
+
+                notify-send --hint=int:transient:1 --urgency=$urgency --icon=utilities-terminal --app-name=fish --expire-time=$__done_notification_duration "$title" "$message"
+
+                if test "$__done_notify_sound" -eq 1
+                    echo -e "\a" # bell sound
+                end
+
+            else if type -q notify-desktop # Linux notify-desktop
+                set -l urgency
+                if test $exit_status -ne 0
+                    set urgency "--urgency=critical"
+                end
+                notify-desktop $urgency --icon=utilities-terminal --app-name=fish "$title" "$message"
+                if test "$__done_notify_sound" -eq 1
+                    echo -e "\a" # bell sound
+                end
+
+            else if uname -a | string match --quiet --ignore-case --regex microsoft
+                __done_windows_notification "$title" "$message"
+
+            else # anything else
+                echo -e "\a" # bell sound
+            end
+
+        end
+    end
+end
+
+function __done_uninstall -e done_uninstall
+    # Erase all __done_* functions
+    functions -e __done_ended
+    functions -e __done_started
+    functions -e __done_get_focused_window_id
+    functions -e __done_is_tmux_window_active
+    functions -e __done_is_screen_window_active
+    functions -e __done_is_process_window_focused
+    functions -e __done_windows_notification
+    functions -e __done_run_powershell_script
+    functions -e __done_humanize_duration
+
+    # Erase __done variables
+    set -e __done_version
+end
diff --git a/fish/config.fish b/fish/config.fish
index 7587fbd..d4418ef 100644
--- a/fish/config.fish
+++ b/fish/config.fish
@@ -1,2 +1,4 @@
 starship init fish | source
-alias gitui="gitui --theme ~/.config/gitui/mocha.ron"
\ No newline at end of file
+alias gitui="gitui --theme ~/.config/gitui/mocha.ron"
+alias bat="bat --theme=Catppuccin-mocha"
+alias cat="bat"
diff --git a/fish/fish_plugins b/fish/fish_plugins
new file mode 100644
index 0000000..66d7ac7
--- /dev/null
+++ b/fish/fish_plugins
@@ -0,0 +1,3 @@
+jorgebucaran/fisher
+catppuccin/fish
+franciscolourenco/done
diff --git a/fish/fish_variables b/fish/fish_variables
index 1a82b8a..758c6bd 100644
--- a/fish/fish_variables
+++ b/fish/fish_variables
@@ -1,31 +1,50 @@
 # This file contains fish universal variable definitions.
 # VERSION: 3.0
+SETUVAR --export PASSWORD_STORE_DIR:/home/skylar/\x2elocal/share/pass
+SETUVAR --export XDG_CONFIG_HOME:/home/skylar/\x2econfig
+SETUVAR --export XDG_DATA_HOME:/home/skylar/\x2elocal/share
 SETUVAR __fish_initialized:3400
-SETUVAR fish_color_autosuggestion:555\x1ebrblack
-SETUVAR fish_color_cancel:\x2dr
-SETUVAR fish_color_command:blue
-SETUVAR fish_color_comment:red
-SETUVAR fish_color_cwd:green
+SETUVAR _fisher_catppuccin_2F_fish_files:\x7e/\x2econfig/fish/themes/Catppuccin\x20Frappe\x2etheme\x1e\x7e/\x2econfig/fish/themes/Catppuccin\x20Latte\x2etheme\x1e\x7e/\x2econfig/fish/themes/Catppuccin\x20Macchiato\x2etheme\x1e\x7e/\x2econfig/fish/themes/Catppuccin\x20Mocha\x2etheme
+SETUVAR _fisher_franciscolourenco_2F_done_files:\x7e/\x2econfig/fish/conf\x2ed/done\x2efish
+SETUVAR _fisher_jorgebucaran_2F_fisher_files:\x7e/\x2econfig/fish/functions/fisher\x2efish\x1e\x7e/\x2econfig/fish/completions/fisher\x2efish
+SETUVAR _fisher_plugins:jorgebucaran/fisher\x1ecatppuccin/fish\x1efranciscolourenco/done
+SETUVAR _fisher_upgraded_to_4_4:\x1d
+SETUVAR fish_color_autosuggestion:6c7086
+SETUVAR fish_color_cancel:f38ba8
+SETUVAR fish_color_command:89b4fa
+SETUVAR fish_color_comment:7f849c
+SETUVAR fish_color_cwd:f9e2af
 SETUVAR fish_color_cwd_root:red
-SETUVAR fish_color_end:green
-SETUVAR fish_color_error:brred
-SETUVAR fish_color_escape:brcyan
+SETUVAR fish_color_end:fab387
+SETUVAR fish_color_error:f38ba8
+SETUVAR fish_color_escape:eba0ac
+SETUVAR fish_color_gray:6c7086
 SETUVAR fish_color_history_current:\x2d\x2dbold
-SETUVAR fish_color_host:normal
-SETUVAR fish_color_host_remote:yellow
-SETUVAR fish_color_normal:normal
-SETUVAR fish_color_operator:brcyan
-SETUVAR fish_color_param:cyan
-SETUVAR fish_color_quote:yellow
-SETUVAR fish_color_redirection:cyan\x1e\x2d\x2dbold
-SETUVAR fish_color_search_match:bryellow\x1e\x2d\x2dbackground\x3dbrblack
-SETUVAR fish_color_selection:white\x1e\x2d\x2dbold\x1e\x2d\x2dbackground\x3dbrblack
-SETUVAR fish_color_status:red
-SETUVAR fish_color_user:brgreen
+SETUVAR fish_color_host:89b4fa
+SETUVAR fish_color_host_remote:a6e3a1
+SETUVAR fish_color_keyword:f38ba8
+SETUVAR fish_color_normal:cdd6f4
+SETUVAR fish_color_operator:f5c2e7
+SETUVAR fish_color_option:a6e3a1
+SETUVAR fish_color_param:f2cdcd
+SETUVAR fish_color_quote:a6e3a1
+SETUVAR fish_color_redirection:f5c2e7
+SETUVAR fish_color_search_match:\x2d\x2dbackground\x3d313244
+SETUVAR fish_color_selection:\x2d\x2dbackground\x3d313244
+SETUVAR fish_color_status:f38ba8
+SETUVAR fish_color_user:94e2d5
 SETUVAR fish_color_valid_path:\x2d\x2dunderline
 SETUVAR fish_key_bindings:fish_default_key_bindings
-SETUVAR fish_pager_color_completion:normal
-SETUVAR fish_pager_color_description:B3A06D\x1eyellow\x1e\x2di
-SETUVAR fish_pager_color_prefix:normal\x1e\x2d\x2dbold\x1e\x2d\x2dunderline
-SETUVAR fish_pager_color_progress:brwhite\x1e\x2d\x2dbackground\x3dcyan
-SETUVAR fish_pager_color_selected_background:\x2dr
+SETUVAR fish_pager_color_background:\x1d
+SETUVAR fish_pager_color_completion:cdd6f4
+SETUVAR fish_pager_color_description:6c7086
+SETUVAR fish_pager_color_prefix:f5c2e7
+SETUVAR fish_pager_color_progress:6c7086
+SETUVAR fish_pager_color_secondary_background:\x1d
+SETUVAR fish_pager_color_secondary_completion:\x1d
+SETUVAR fish_pager_color_secondary_description:\x1d
+SETUVAR fish_pager_color_secondary_prefix:\x1d
+SETUVAR fish_pager_color_selected_background:\x1d
+SETUVAR fish_pager_color_selected_completion:\x1d
+SETUVAR fish_pager_color_selected_description:\x1d
+SETUVAR fish_pager_color_selected_prefix:\x1d
diff --git a/fish/functions/fisher.fish b/fish/functions/fisher.fish
new file mode 100644
index 0000000..b1513d3
--- /dev/null
+++ b/fish/functions/fisher.fish
@@ -0,0 +1,240 @@
+function fisher --argument-names cmd --description "A plugin manager for Fish"
+    set --query fisher_path || set --local fisher_path $__fish_config_dir
+    set --local fisher_version 4.4.4
+    set --local fish_plugins $__fish_config_dir/fish_plugins
+
+    switch "$cmd"
+        case -v --version
+            echo "fisher, version $fisher_version"
+        case "" -h --help
+            echo "Usage: fisher install <plugins...>  Install plugins"
+            echo "       fisher remove  <plugins...>  Remove installed plugins"
+            echo "       fisher update  <plugins...>  Update installed plugins"
+            echo "       fisher update                Update all installed plugins"
+            echo "       fisher list    [<regex>]     List installed plugins matching regex"
+            echo "Options:"
+            echo "       -v, --version  Print version"
+            echo "       -h, --help     Print this help message"
+            echo "Variables:"
+            echo "       \$fisher_path  Plugin installation path. Default: $__fish_config_dir" | string replace --regex -- $HOME \~
+        case ls list
+            string match --entire --regex -- "$argv[2]" $_fisher_plugins
+        case install update remove
+            isatty || read --local --null --array stdin && set --append argv $stdin
+
+            set --local install_plugins
+            set --local update_plugins
+            set --local remove_plugins
+            set --local arg_plugins $argv[2..-1]
+            set --local old_plugins $_fisher_plugins
+            set --local new_plugins
+
+            test -e $fish_plugins && set --local file_plugins (string match --regex -- '^[^\s]+$' <$fish_plugins)
+
+            if ! set --query argv[2]
+                if test "$cmd" != update
+                    echo "fisher: Not enough arguments for command: \"$cmd\"" >&2 && return 1
+                else if ! set --query file_plugins
+                    echo "fisher: \"$fish_plugins\" file not found: \"$cmd\"" >&2 && return 1
+                end
+                set arg_plugins $file_plugins
+            end
+
+            for plugin in $arg_plugins
+                set plugin (test -e "$plugin" && realpath $plugin || string lower -- $plugin)
+                contains -- "$plugin" $new_plugins || set --append new_plugins $plugin
+            end
+
+            if set --query argv[2]
+                for plugin in $new_plugins
+                    if contains -- "$plugin" $old_plugins
+                        test "$cmd" = remove &&
+                            set --append remove_plugins $plugin ||
+                            set --append update_plugins $plugin
+                    else if test "$cmd" = install
+                        set --append install_plugins $plugin
+                    else
+                        echo "fisher: Plugin not installed: \"$plugin\"" >&2 && return 1
+                    end
+                end
+            else
+                for plugin in $new_plugins
+                    contains -- "$plugin" $old_plugins &&
+                        set --append update_plugins $plugin ||
+                        set --append install_plugins $plugin
+                end
+
+                for plugin in $old_plugins
+                    contains -- "$plugin" $new_plugins || set --append remove_plugins $plugin
+                end
+            end
+
+            set --local pid_list
+            set --local source_plugins
+            set --local fetch_plugins $update_plugins $install_plugins
+            set --local fish_path (status fish-path)
+
+            echo (set_color --bold)fisher $cmd version $fisher_version(set_color normal)
+
+            for plugin in $fetch_plugins
+                set --local source (command mktemp -d)
+                set --append source_plugins $source
+
+                command mkdir -p $source/{completions,conf.d,themes,functions}
+
+                $fish_path --command "
+                    if test -e $plugin
+                        command cp -Rf $plugin/* $source
+                    else
+                        set temp (command mktemp -d)
+                        set repo (string split -- \@ $plugin) || set repo[2] HEAD
+
+                        if set path (string replace --regex -- '^(https://)?gitlab.com/' '' \$repo[1])
+                            set name (string split -- / \$path)[-1]
+                            set url https://gitlab.com/\$path/-/archive/\$repo[2]/\$name-\$repo[2].tar.gz
+                        else
+                            set url https://api.github.com/repos/\$repo[1]/tarball/\$repo[2]
+                        end
+
+                        echo Fetching (set_color --underline)\$url(set_color normal)
+
+                        if command curl -q --silent -L \$url | command tar -xzC \$temp -f - 2>/dev/null
+                            command cp -Rf \$temp/*/* $source
+                        else
+                            echo fisher: Invalid plugin name or host unavailable: \\\"$plugin\\\" >&2
+                            command rm -rf $source
+                        end
+
+                        command rm -rf \$temp
+                    end
+
+                    set files $source/* && string match --quiet --regex -- .+\.fish\\\$ \$files
+                " &
+
+                set --append pid_list (jobs --last --pid)
+            end
+
+            wait $pid_list 2>/dev/null
+
+            for plugin in $fetch_plugins
+                if set --local source $source_plugins[(contains --index -- "$plugin" $fetch_plugins)] && test ! -e $source
+                    if set --local index (contains --index -- "$plugin" $install_plugins)
+                        set --erase install_plugins[$index]
+                    else
+                        set --erase update_plugins[(contains --index -- "$plugin" $update_plugins)]
+                    end
+                end
+            end
+
+            for plugin in $update_plugins $remove_plugins
+                if set --local index (contains --index -- "$plugin" $_fisher_plugins)
+                    set --local plugin_files_var _fisher_(string escape --style=var -- $plugin)_files
+
+                    if contains -- "$plugin" $remove_plugins
+                        for name in (string replace --filter --regex -- '.+/conf\.d/([^/]+)\.fish$' '$1' $$plugin_files_var)
+                            emit {$name}_uninstall
+                        end
+                        printf "%s\n" Removing\ (set_color red --bold)$plugin(set_color normal) "         "$$plugin_files_var | string replace -- \~ ~
+                        set --erase _fisher_plugins[$index]
+                    end
+
+                    command rm -rf (string replace -- \~ ~ $$plugin_files_var)
+
+                    functions --erase (string replace --filter --regex -- '.+/functions/([^/]+)\.fish$' '$1' $$plugin_files_var)
+
+                    for name in (string replace --filter --regex -- '.+/completions/([^/]+)\.fish$' '$1' $$plugin_files_var)
+                        complete --erase --command $name
+                    end
+
+                    set --erase $plugin_files_var
+                end
+            end
+
+            if set --query update_plugins[1] || set --query install_plugins[1]
+                command mkdir -p $fisher_path/{functions,themes,conf.d,completions}
+            end
+
+            for plugin in $update_plugins $install_plugins
+                set --local source $source_plugins[(contains --index -- "$plugin" $fetch_plugins)]
+                set --local files $source/{functions,themes,conf.d,completions}/*
+
+                if set --local index (contains --index -- $plugin $install_plugins)
+                    set --local user_files $fisher_path/{functions,themes,conf.d,completions}/*
+                    set --local conflict_files
+
+                    for file in (string replace -- $source/ $fisher_path/ $files)
+                        contains -- $file $user_files && set --append conflict_files $file
+                    end
+
+                    if set --query conflict_files[1] && set --erase install_plugins[$index]
+                        echo -s "fisher: Cannot install \"$plugin\": please remove or move conflicting files first:" \n"        "$conflict_files >&2
+                        continue
+                    end
+                end
+
+                for file in (string replace -- $source/ "" $files)
+                    command cp -RLf $source/$file $fisher_path/$file
+                end
+
+                set --local plugin_files_var _fisher_(string escape --style=var -- $plugin)_files
+
+                set --query files[1] && set --universal $plugin_files_var (string replace -- $source $fisher_path $files | string replace -- ~ \~)
+
+                contains -- $plugin $_fisher_plugins || set --universal --append _fisher_plugins $plugin
+                contains -- $plugin $install_plugins && set --local event install || set --local event update
+
+                printf "%s\n" Installing\ (set_color --bold)$plugin(set_color normal) "           "$$plugin_files_var | string replace -- \~ ~
+
+                for file in (string match --regex -- '.+/[^/]+\.fish$' $$plugin_files_var | string replace -- \~ ~)
+                    source $file
+                    if set --local name (string replace --regex -- '.+conf\.d/([^/]+)\.fish$' '$1' $file)
+                        emit {$name}_$event
+                    end
+                end
+            end
+
+            command rm -rf $source_plugins
+
+            if set --query _fisher_plugins[1]
+                set --local commit_plugins
+
+                for plugin in $file_plugins
+                    contains -- (string lower -- $plugin) (string lower -- $_fisher_plugins) && set --append commit_plugins $plugin
+                end
+
+                for plugin in $_fisher_plugins
+                    contains -- (string lower -- $plugin) (string lower -- $commit_plugins) || set --append commit_plugins $plugin
+                end
+
+                printf "%s\n" $commit_plugins >$fish_plugins
+            else
+                set --erase _fisher_plugins
+                command rm -f $fish_plugins
+            end
+
+            set --local total (count $install_plugins) (count $update_plugins) (count $remove_plugins)
+
+            test "$total" != "0 0 0" && echo (string join ", " (
+                test $total[1] = 0 || echo "Installed $total[1]") (
+                test $total[2] = 0 || echo "Updated $total[2]") (
+                test $total[3] = 0 || echo "Removed $total[3]")
+            ) plugin/s
+        case \*
+            echo "fisher: Unknown command: \"$cmd\"" >&2 && return 1
+    end
+end
+
+if ! set --query _fisher_upgraded_to_4_4
+    set --universal _fisher_upgraded_to_4_4
+    if functions --query _fisher_list
+        set --query XDG_DATA_HOME[1] || set --local XDG_DATA_HOME ~/.local/share
+        command rm -rf $XDG_DATA_HOME/fisher
+        functions --erase _fisher_{list,plugin_parse}
+        fisher update >/dev/null 2>/dev/null
+    else
+        for var in (set --names | string match --entire --regex '^_fisher_.+_files$')
+            set $var (string replace -- ~ \~ $$var)
+        end
+        functions --erase _fisher_fish_postexec
+    end
+end
diff --git a/fish/themes/Catppuccin Frappe.theme b/fish/themes/Catppuccin Frappe.theme
new file mode 100644
index 0000000..3dc51d4
--- /dev/null
+++ b/fish/themes/Catppuccin Frappe.theme	
@@ -0,0 +1,30 @@
+# name: 'Catppuccin frappe'
+# url: 'https://github.com/catppuccin/fish'
+# preferred_background: 303446
+
+fish_color_normal c6d0f5
+fish_color_command 8caaee
+fish_color_param eebebe
+fish_color_keyword e78284
+fish_color_quote a6d189
+fish_color_redirection f4b8e4
+fish_color_end ef9f76
+fish_color_comment 838ba7
+fish_color_error e78284
+fish_color_gray 737994
+fish_color_selection --background=414559
+fish_color_search_match --background=414559
+fish_color_option a6d189
+fish_color_operator f4b8e4
+fish_color_escape ea999c
+fish_color_autosuggestion 737994
+fish_color_cancel e78284
+fish_color_cwd e5c890
+fish_color_user 81c8be
+fish_color_host 8caaee
+fish_color_host_remote a6d189
+fish_color_status e78284
+fish_pager_color_progress 737994
+fish_pager_color_prefix f4b8e4
+fish_pager_color_completion c6d0f5
+fish_pager_color_description 737994
diff --git a/fish/themes/Catppuccin Latte.theme b/fish/themes/Catppuccin Latte.theme
new file mode 100644
index 0000000..23a514e
--- /dev/null
+++ b/fish/themes/Catppuccin Latte.theme	
@@ -0,0 +1,30 @@
+# name: 'Catppuccin latte'
+# url: 'https://github.com/catppuccin/fish'
+# preferred_background: eff1f5
+
+fish_color_normal 4c4f69
+fish_color_command 1e66f5
+fish_color_param dd7878
+fish_color_keyword d20f39
+fish_color_quote 40a02b
+fish_color_redirection ea76cb
+fish_color_end fe640b
+fish_color_comment 8c8fa1
+fish_color_error d20f39
+fish_color_gray 9ca0b0
+fish_color_selection --background=ccd0da
+fish_color_search_match --background=ccd0da
+fish_color_option 40a02b
+fish_color_operator ea76cb
+fish_color_escape e64553
+fish_color_autosuggestion 9ca0b0
+fish_color_cancel d20f39
+fish_color_cwd df8e1d
+fish_color_user 179299
+fish_color_host_remote 40a02b
+fish_color_host 1e66f5
+fish_color_status d20f39
+fish_pager_color_progress 9ca0b0
+fish_pager_color_prefix ea76cb
+fish_pager_color_completion 4c4f69
+fish_pager_color_description 9ca0b0
diff --git a/fish/themes/Catppuccin Macchiato.theme b/fish/themes/Catppuccin Macchiato.theme
new file mode 100644
index 0000000..e90b630
--- /dev/null
+++ b/fish/themes/Catppuccin Macchiato.theme	
@@ -0,0 +1,30 @@
+# name: 'Catppuccin macchiato'
+# url: 'https://github.com/catppuccin/fish'
+# preferred_background: 24273a
+
+fish_color_normal cad3f5
+fish_color_command 8aadf4
+fish_color_param f0c6c6
+fish_color_keyword ed8796
+fish_color_quote a6da95
+fish_color_redirection f5bde6
+fish_color_end f5a97f
+fish_color_comment 8087a2
+fish_color_error ed8796
+fish_color_gray 6e738d
+fish_color_selection --background=363a4f
+fish_color_search_match --background=363a4f
+fish_color_option a6da95
+fish_color_operator f5bde6
+fish_color_escape ee99a0
+fish_color_autosuggestion 6e738d
+fish_color_cancel ed8796
+fish_color_cwd eed49f
+fish_color_user 8bd5ca
+fish_color_host 8aadf4
+fish_color_host_remote a6da95
+fish_color_status ed8796
+fish_pager_color_progress 6e738d
+fish_pager_color_prefix f5bde6
+fish_pager_color_completion cad3f5
+fish_pager_color_description 6e738d
diff --git a/fish/themes/Catppuccin Mocha.theme b/fish/themes/Catppuccin Mocha.theme
new file mode 100644
index 0000000..2b0c71c
--- /dev/null
+++ b/fish/themes/Catppuccin Mocha.theme	
@@ -0,0 +1,30 @@
+# name: 'Catppuccin mocha'
+# url: 'https://github.com/catppuccin/fish'
+# preferred_background: 1e1e2e
+
+fish_color_normal cdd6f4
+fish_color_command 89b4fa
+fish_color_param f2cdcd
+fish_color_keyword f38ba8
+fish_color_quote a6e3a1
+fish_color_redirection f5c2e7
+fish_color_end fab387
+fish_color_comment 7f849c
+fish_color_error f38ba8
+fish_color_gray 6c7086
+fish_color_selection --background=313244
+fish_color_search_match --background=313244
+fish_color_option a6e3a1
+fish_color_operator f5c2e7
+fish_color_escape eba0ac
+fish_color_autosuggestion 6c7086
+fish_color_cancel f38ba8
+fish_color_cwd f9e2af
+fish_color_user 94e2d5
+fish_color_host 89b4fa
+fish_color_host_remote a6e3a1
+fish_color_status f38ba8
+fish_pager_color_progress 6c7086
+fish_pager_color_prefix f5c2e7
+fish_pager_color_completion cdd6f4
+fish_pager_color_description 6c7086