b5f4e68635
* gnu/services.scm (<service>)[inputs]: Remove. * gnu/system.scm (links): Remove. (etc-directory): Add PASSWD and SHADOW to #:inputs. (operating-system-boot-script): Pass ETC to 'dmd-configuration-file'. (operating-system-derivation): Remove EXTRAS from the union. * gnu/system/linux.scm (pam-service->configuration): Rewrite in terms of 'gexp->derivation'. Compute the contents on the build side. Expect 'arguments' to contain a list of gexps. (pam-services->directory): Rewrite in terms of 'gexp->derivation'. (unix-pam-service): Change 'arguments' to a list of one gexp. * gnu/system/shadow.scm (<user-account>)[inputs]: Remove. [shell]: Change default value to a gexp. (passwd-file): Rewrite in terms of 'gexp->derivation'. Compute contents on the build side. * gnu/services/base.scm (host-name-service, mingetty-service, nscd-service, syslog-service, guix-service): Change 'start' and 'stop' to gexps; remove 'inputs' field. (guix-build-accounts): Change 'shell' field to a gexp. * gnu/services/networking.scm (static-networking-service): Change 'start' and 'stop' to gexps; remove 'inputs' field. * gnu/services/xorg.scm (slim-service): Likewise. * gnu/services/dmd.scm (dmd-configuration-file): Expect ETC to be a derivation. Change 'config' to a gexp. Use 'gexp->file' instead of 'text-file'. * doc/guix.texi (Defining Services): Update nscd example with gexps, and without 'inputs'. Add xref to "G-Expressions".
83 lines
3.5 KiB
Scheme
83 lines
3.5 KiB
Scheme
;;; GNU Guix --- Functional package management for GNU
|
|
;;; Copyright © 2013, 2014 Ludovic Courtès <ludo@gnu.org>
|
|
;;;
|
|
;;; This file is part of GNU Guix.
|
|
;;;
|
|
;;; GNU Guix is free software; you can redistribute it and/or modify it
|
|
;;; under the terms of the GNU General Public License as published by
|
|
;;; the Free Software Foundation; either version 3 of the License, or (at
|
|
;;; your option) any later version.
|
|
;;;
|
|
;;; GNU Guix is distributed in the hope that it will be useful, but
|
|
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;;; GNU General Public License for more details.
|
|
;;;
|
|
;;; You should have received a copy of the GNU General Public License
|
|
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
|
|
|
|
(define-module (gnu services networking)
|
|
#:use-module (gnu services)
|
|
#:use-module (gnu packages admin)
|
|
#:use-module (gnu packages linux)
|
|
#:use-module (guix gexp)
|
|
#:use-module (guix monads)
|
|
#:export (static-networking-service))
|
|
|
|
;;; Commentary:
|
|
;;;
|
|
;;; Networking services.
|
|
;;;
|
|
;;; Code:
|
|
|
|
(define* (static-networking-service interface ip
|
|
#:key
|
|
gateway
|
|
(name-servers '())
|
|
(inetutils inetutils)
|
|
(net-tools net-tools))
|
|
"Return a service that starts INTERFACE with address IP. If GATEWAY is
|
|
true, it must be a string specifying the default network gateway."
|
|
|
|
;; TODO: Eventually we should do this using Guile's networking procedures,
|
|
;; like 'configure-qemu-networking' does, but the patch that does this is
|
|
;; not yet in stock Guile.
|
|
(with-monad %store-monad
|
|
(return
|
|
(service
|
|
(documentation
|
|
(string-append "Set up networking on the '" interface
|
|
"' interface using a static IP address."))
|
|
(provision '(networking))
|
|
(start #~(lambda _
|
|
;; Return #t if successfully started.
|
|
(and (zero? (system* (string-append #$inetutils
|
|
"/bin/ifconfig")
|
|
#$interface #$ip "up"))
|
|
#$(if gateway
|
|
#~(zero? (system* (string-append #$net-tools
|
|
"/sbin/route")
|
|
"add" "-net" "default"
|
|
"gw" #$gateway))
|
|
#t)
|
|
#$(if (pair? name-servers)
|
|
#~(call-with-output-file "/etc/resolv.conf"
|
|
(lambda (port)
|
|
(display
|
|
"# Generated by 'static-networking-service'.\n"
|
|
port)
|
|
(for-each (lambda (server)
|
|
(format port "nameserver ~a~%"
|
|
server))
|
|
'#$name-servers)))
|
|
#t))))
|
|
(stop #~(lambda _
|
|
;; Return #f is successfully stopped.
|
|
(not (and (system* (string-append #$inetutils "/sbin/ifconfig")
|
|
#$interface "down")
|
|
(system* (string-append #$net-tools "/sbin/route")
|
|
"del" "-net" "default")))))
|
|
(respawn? #f)))))
|
|
|
|
;;; networking.scm ends here
|