df46bef48e
Fixes <https://issues.guix.gnu.org/50676>. Reported by Mathieu Othacehe <othacehe@gnu.org>. Commita779363b6awas partially incorrect: references passed to #:allowed-references or #:references-graphs *can* be lowered as references to grafted elements. This is for example the case when doing: (computed-file "partition.img" exp #:options `(#:references-graphs ,inputs)) Here INPUTS must be lowered as a reference to suitably grafted elements. Failing to do that, the reference graph will not match the actual INPUTS. However, when building a package, those references must indeed refer only to ungrafted packages. This commit preserves that by having build systems pass #:graft? #f. * guix/gexp.scm (lower-reference-graphs, lower-references): Remove uses of 'without-grafting'. This revertsa779363b6a. * guix/build-system/cmake.scm (cmake-build, cmake-cross-build): Pass #:graft? #f. * guix/build-system/glib-or-gtk.scm (glib-or-gtk-build) (glib-or-gtk-cross-build): Likewise. * guix/build-system/gnu.scm (gnu-build, gnu-cross-build): Likewise. * guix/build-system/meson.scm (meson-build, meson-cross-build): Likewise. * guix/build-system/trivial.scm (trivial-build, trivial-cross-build): Likewise. * tests/gexp.scm ("lower-object, computed-file + grafts"): New test. * tests/packages.scm ("trivial with #:allowed-references + grafts"): New test.
100 lines
4 KiB
Scheme
100 lines
4 KiB
Scheme
;;; GNU Guix --- Functional package management for GNU
|
|
;;; Copyright © 2012, 2013, 2014, 2015, 2018, 2021 Ludovic Courtès <ludo@gnu.org>
|
|
;;;
|
|
;;; This file is part of GNU Guix.
|
|
;;;
|
|
;;; GNU Guix is free software; you can redistribute it and/or modify it
|
|
;;; under the terms of the GNU General Public License as published by
|
|
;;; the Free Software Foundation; either version 3 of the License, or (at
|
|
;;; your option) any later version.
|
|
;;;
|
|
;;; GNU Guix is distributed in the hope that it will be useful, but
|
|
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;;; GNU General Public License for more details.
|
|
;;;
|
|
;;; You should have received a copy of the GNU General Public License
|
|
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
|
|
|
|
(define-module (guix build-system trivial)
|
|
#:use-module (guix store)
|
|
#:use-module (guix utils)
|
|
#:use-module (guix gexp)
|
|
#:use-module (guix monads)
|
|
#:use-module (guix packages)
|
|
#:use-module (guix build-system)
|
|
#:use-module (ice-9 match)
|
|
#:export (trivial-build-system))
|
|
|
|
(define* (lower name
|
|
#:key source inputs native-inputs outputs system target
|
|
guile builder (modules '()) allowed-references)
|
|
"Return a bag for NAME."
|
|
(bag
|
|
(name name)
|
|
(system system)
|
|
(target target)
|
|
(host-inputs `(,@(if source
|
|
`(("source" ,source))
|
|
'())
|
|
,@inputs))
|
|
(build-inputs native-inputs)
|
|
(outputs outputs)
|
|
(build (if target trivial-cross-build trivial-build))
|
|
(arguments `(#:guile ,guile
|
|
#:builder ,builder
|
|
#:modules ,modules
|
|
#:allowed-references ,allowed-references))))
|
|
|
|
(define* (trivial-build name inputs
|
|
#:key
|
|
outputs guile
|
|
system builder (modules '())
|
|
search-paths allowed-references)
|
|
"Run build expression BUILDER, an expression, for SYSTEM. SOURCE is
|
|
ignored."
|
|
(mlet %store-monad ((guile (package->derivation (or guile (default-guile))
|
|
system #:graft? #f))
|
|
(builder -> (if (pair? builder)
|
|
(sexp->gexp builder)
|
|
builder)))
|
|
(gexp->derivation name (with-build-variables inputs outputs builder)
|
|
#:system system
|
|
#:target #f
|
|
#:graft? #f
|
|
#:modules modules
|
|
#:allowed-references allowed-references
|
|
#:guile-for-build guile)))
|
|
|
|
(define* (trivial-cross-build name
|
|
#:key
|
|
target
|
|
source build-inputs target-inputs host-inputs
|
|
outputs guile system builder (modules '())
|
|
search-paths native-search-paths
|
|
allowed-references)
|
|
"Run build expression BUILDER, an expression, for SYSTEM. SOURCE is
|
|
ignored."
|
|
(mlet %store-monad ((guile (package->derivation (or guile (default-guile))
|
|
system #:graft? #f))
|
|
(builder -> (if (pair? builder)
|
|
(sexp->gexp builder)
|
|
builder)))
|
|
(gexp->derivation name (with-build-variables
|
|
(append build-inputs target-inputs host-inputs)
|
|
outputs
|
|
builder)
|
|
#:system system
|
|
#:target target
|
|
#:graft? #f
|
|
#:modules modules
|
|
#:allowed-references allowed-references
|
|
#:guile-for-build guile)))
|
|
|
|
(define trivial-build-system
|
|
(build-system
|
|
(name 'trivial)
|
|
(description
|
|
"Trivial build system, to run arbitrary Scheme build expressions")
|
|
(lower lower)))
|