b5f4e68635
* gnu/services.scm (<service>)[inputs]: Remove. * gnu/system.scm (links): Remove. (etc-directory): Add PASSWD and SHADOW to #:inputs. (operating-system-boot-script): Pass ETC to 'dmd-configuration-file'. (operating-system-derivation): Remove EXTRAS from the union. * gnu/system/linux.scm (pam-service->configuration): Rewrite in terms of 'gexp->derivation'. Compute the contents on the build side. Expect 'arguments' to contain a list of gexps. (pam-services->directory): Rewrite in terms of 'gexp->derivation'. (unix-pam-service): Change 'arguments' to a list of one gexp. * gnu/system/shadow.scm (<user-account>)[inputs]: Remove. [shell]: Change default value to a gexp. (passwd-file): Rewrite in terms of 'gexp->derivation'. Compute contents on the build side. * gnu/services/base.scm (host-name-service, mingetty-service, nscd-service, syslog-service, guix-service): Change 'start' and 'stop' to gexps; remove 'inputs' field. (guix-build-accounts): Change 'shell' field to a gexp. * gnu/services/networking.scm (static-networking-service): Change 'start' and 'stop' to gexps; remove 'inputs' field. * gnu/services/xorg.scm (slim-service): Likewise. * gnu/services/dmd.scm (dmd-configuration-file): Expect ETC to be a derivation. Change 'config' to a gexp. Use 'gexp->file' instead of 'text-file'. * doc/guix.texi (Defining Services): Update nscd example with gexps, and without 'inputs'. Add xref to "G-Expressions".
82 lines
3.1 KiB
Scheme
82 lines
3.1 KiB
Scheme
;;; GNU Guix --- Functional package management for GNU
|
|
;;; Copyright © 2013, 2014 Ludovic Courtès <ludo@gnu.org>
|
|
;;;
|
|
;;; This file is part of GNU Guix.
|
|
;;;
|
|
;;; GNU Guix is free software; you can redistribute it and/or modify it
|
|
;;; under the terms of the GNU General Public License as published by
|
|
;;; the Free Software Foundation; either version 3 of the License, or (at
|
|
;;; your option) any later version.
|
|
;;;
|
|
;;; GNU Guix is distributed in the hope that it will be useful, but
|
|
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;;; GNU General Public License for more details.
|
|
;;;
|
|
;;; You should have received a copy of the GNU General Public License
|
|
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
|
|
|
|
(define-module (gnu services dmd)
|
|
#:use-module (guix gexp)
|
|
#:use-module (guix monads)
|
|
#:use-module (gnu services)
|
|
#:use-module (ice-9 match)
|
|
#:use-module (srfi srfi-1)
|
|
#:export (dmd-configuration-file))
|
|
|
|
;;; Commentary:
|
|
;;;
|
|
;;; Instantiating system services as a dmd configuration file.
|
|
;;;
|
|
;;; Code:
|
|
|
|
(define (dmd-configuration-file services etc)
|
|
"Return the dmd configuration file for SERVICES, that initializes /etc from
|
|
ETC (the derivation that builds the /etc directory) on startup."
|
|
(define config
|
|
#~(begin
|
|
(use-modules (ice-9 ftw))
|
|
|
|
(register-services
|
|
#$@(map (lambda (service)
|
|
#~(make <service>
|
|
#:docstring '#$(service-documentation service)
|
|
#:provides '#$(service-provision service)
|
|
#:requires '#$(service-requirement service)
|
|
#:respawn? '#$(service-respawn? service)
|
|
#:start #$(service-start service)
|
|
#:stop #$(service-stop service)))
|
|
services))
|
|
|
|
;; /etc is a mixture of static and dynamic settings. Here is where we
|
|
;; initialize it from the static part.
|
|
(format #t "populating /etc from ~a...~%" #$etc)
|
|
(let ((rm-f (lambda (f)
|
|
(false-if-exception (delete-file f)))))
|
|
(rm-f "/etc/static")
|
|
(symlink #$etc "/etc/static")
|
|
(for-each (lambda (file)
|
|
;; TODO: Handle 'shadow' specially so that changed
|
|
;; password aren't lost.
|
|
(let ((target (string-append "/etc/" file))
|
|
(source (string-append "/etc/static/" file)))
|
|
(rm-f target)
|
|
(symlink source target)))
|
|
(scandir #$etc
|
|
(lambda (file)
|
|
(not (member file '("." ".."))))))
|
|
|
|
;; Prevent ETC from being GC'd.
|
|
(rm-f "/var/guix/gcroots/etc-directory")
|
|
(symlink #$etc "/var/guix/gcroots/etc-directory"))
|
|
|
|
;; guix-daemon 0.6 aborts if 'PATH' is undefined, so work around it.
|
|
(setenv "PATH" "/run/current-system/bin")
|
|
|
|
(format #t "starting services...~%")
|
|
(for-each start '#$(append-map service-provision services))))
|
|
|
|
(gexp->file "dmd.conf" config))
|
|
|
|
;;; dmd.scm ends here
|